Parallelism().set(nproc=8)

%display latex

Characteristic Classes in SageMath

Michael Jung

Vrije Universiteit Amsterdam

October 30, 2020

Contents

1. Mixed Differential Forms
2. Example: Euler Class
3. Characteristic Classes in General
4. Implementation Details and Improvements
5. Future Prospects

Mixed Differential Forms

• $n$-dimensional smooth manifold $M$

• $\mathbb{K}=\mathbb{R},\mathbb{C}$

• vector space of $\mathbb{K}$-valued $k$-forms $\Omega^k(M; \mathbb{K})$

• space of mixed differential forms:

$$\nonumber\Omega^*(M;\mathbb{K}) := \bigoplus^n_{k=0} \Omega^k(M;\mathbb{K})$$

• Wedge product $\wedge:\Omega^k(M, \mathbb{K}) \times \Omega^l(M, \mathbb{K}) \to \Omega^{k + l}(M, \mathbb{K})$ gives structure of a graded algebra

Example on $\mathbb{R}^2$

Define manifold:

M = Manifold(2, 'R^2', latex_name=r'\mathbb{R}^2')
X.<x,y> = M.chart()

Algebra of mixed forms:

Ω = M.mixed_form_algebra(); Ω

$$\newcommand{\Bold}[1]{\mathbf{#1}}\Omega^*\left(\mathbb{R}^2\right)$$

Ω.category()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathbf{GradedAlgebras}(\mathbf{Algebras}_{\text{SR}})$$

f = M.scalar_field(name='f')
ω1 = M.diff_form(1, name='omega_1', latex_name=r'\omega_1')
ω2 = M.diff_form(2, name='omega_2', latex_name=r'\omega_2')
η = M.diff_form(1, name='eta', latex_name=r'\eta')

f.set_expr(x^2)
ω1[:]   = y, 2*x
ω2[0,1] = 4*x^3
η [:]   = x, y

Consider some predefined forms:

f.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} f:& \mathbb{R}^2 & \longrightarrow & \mathbb{R} \\ & \left(x, y\right) & \longmapsto & x^{2} \end{array}$$

ω1.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\omega_1 = y \mathrm{d} x + 2 \, x \mathrm{d} y$$

ω2.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\omega_2 = 4 \, x^{3} \mathrm{d} x\wedge \mathrm{d} y$$

η.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\eta = x \mathrm{d} x + y \mathrm{d} y$$

Define a mixed form:

A = M.mixed_form(name='A'); print(A)

Mixed differential form A on the 2-dimensional differentiable manifold R^2

It shall consist of the differential forms $f, \omega_1, \omega_2$. The forms are assigned by using index operations:

A[:] = [f,ω1,ω2]; A.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}A = f + \omega_1 + \omega_2$$

A.display_expansion()

$$\newcommand{\Bold}[1]{\mathbf{#1}}A = \left[ x^{2} \right]_0 + \left[ y \mathrm{d} x + 2 \, x \mathrm{d} y \right]_1 + \left[ 4 \, x^{3} \mathrm{d} x\wedge \mathrm{d} y \right]_2$$

Another mixed form:

B = M.mixed_form([2,η,0], name='B'); B.display_expansion()

$$\newcommand{\Bold}[1]{\mathbf{#1}}B = \left[ 2 \right]_0 + \left[ x \mathrm{d} x + y \mathrm{d} y \right]_1 + \left[ 0 \right]_2$$

The multiplication is executed degree wise:

all((A * B)[k] == sum(A[j].wedge(B[k - j])
                      for j in range(k + 1))
    for k in Ω.irange())

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Recall: Curvature Forms

Definition

Let $M$ be a smooth manifold and $R$ be the Riemann tensor w.r.t. to some connection $\nabla$. We define the curvature form matrix $\Omega^\nabla$ w.r.t. the frame $(e_1, \ldots, e_n)$ via:

$$R(X,Y) \, e_i = \sum_{j=1}^n \Omega_{ij}(X,Y) \, e_j.$$

• $\Omega^\nabla$ transforms as $T^{-1} \Omega T$ under change of frame $T\colon U \to E$.

• $(e_1, \ldots, e_n)$ orthonormal w.r.t. compatible metric $\Rightarrow$ $\Omega^\nabla$ skew-symmetric / skew-Hermitian

Gauß-Bonnet

Theorem (Gauß-Bonnet)

Let $M$ be an $2$-dimensional closed oriented Riemannian manifold. Then

$$\int_M \frac{\Omega^g_{12}}{2 \pi} = \chi(M),$$

where $\Omega^g$ is the from $g$ induced curvature form matrix w.r.t. an orthonormal oriented frame and $\chi(M)$ is the Euler characteristic of $M$.

• Left hand side is computable by Sage!

S2 = Manifold(2, name='S^2', latex_name=r'\mathbb{S}^2',
             structure='Riemannian', start_index=1)
U = S2.open_subset('U') ; V = S2.open_subset('V')
S2.declare_union(U,V)   # M is the union of U and V
stereoN.<x,y> = U.chart()
stereoS.<xp,yp> = V.chart("xp:x' yp:y'")

Example: Euler Characteristic

S2

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathbb{S}^2$$

S2.atlas()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left(U,(x, y)\right), \left(V,({x'}, {y'})\right)\right]$$

stereoN_to_stereoS = stereoN.transition_map(stereoS,
                                (x/(x^2+y^2), y/(x^2+y^2)),
                                intersection_name='W',
                                restrictions1= x^2+y^2!=0,
                                restrictions2= xp^2+yp^2!=0)
stereoS_to_stereoN = stereoN_to_stereoS.inverse()

stereoN_to_stereoS.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} {x'} & = & \frac{x}{x^{2} + y^{2}} \\ {y'} & = & \frac{y}{x^{2} + y^{2}} \end{array}\right.$$

E = Manifold(3, 'R^3', latex_name=r'\mathbb{R}^3', start_index=1)
cart.<X,Y,Z> = E.chart()
h = E.metric('h')
h[1,1], h[2,2], h[3, 3] = 1, 1, 1

ι = S2.diff_map(E, {(stereoN, cart):
                       [2*x/(1+x^2+y^2), 2*y/(1+x^2+y^2),
                        (1-x^2-y^2)/(1+x^2+y^2)],
                       (stereoS, cart):
                       [2*xp/(1+xp^2+yp^2), 2*yp/(1+xp^2+yp^2),
                        (xp^2+yp^2-1)/(1+xp^2+yp^2)]},
                   name='iota', latex_name=r'\iota')

g = S2.metric()
g.set(ι.pullback(h))
g[1,1].factor(); g[2,2].factor()
nab = g.connection()

g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = \frac{4}{{\left(x^{2} + y^{2} + 1\right)}^{2}} \mathrm{d} x\otimes \mathrm{d} x + \frac{4}{{\left(x^{2} + y^{2} + 1\right)}^{2}} \mathrm{d} y\otimes \mathrm{d} y$$

ΩU = [[nab.curvature_form(i,j,stereoN.frame()) for j in S2.irange()] for i in S2.irange()]
ΩV = [[nab.curvature_form(i,j,stereoS.frame()) for j in S2.irange()] for i in S2.irange()]

cmatrices = {stereoN.frame(): ΩU, stereoS.frame(): ΩV}; cmatrices

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left\{\left(U, \left(\frac{\partial}{\partial x },\frac{\partial}{\partial y }\right)\right) : \left[\left[\Omega^1_{\ \, 1}, \Omega^1_{\ \, 2}\right], \left[\Omega^2_{\ \, 1}, \Omega^2_{\ \, 2}\right]\right], \left(V, \left(\frac{\partial}{\partial {x'} },\frac{\partial}{\partial {y'} }\right)\right) : \left[\left[\Omega^1_{\ \, 1}, \Omega^1_{\ \, 2}\right], \left[\Omega^2_{\ \, 1}, \Omega^2_{\ \, 2}\right]\right]\right\}$$

Euler Class

TS2 = S2.tangent_bundle(); TS2

$$\newcommand{\Bold}[1]{\mathbf{#1}}T\mathbb{S}^2\to \mathbb{S}^2$$

e_class = TS2.characteristic_class('Euler'); e_class

$$\newcommand{\Bold}[1]{\mathbf{#1}}e(T\mathbb{S}^2)$$

e_class_form = e_class.get_form(nab, cmatrices)
e_class_form.display_expansion()

$$\newcommand{\Bold}[1]{\mathbf{#1}}e(T\mathbb{S}^2, \nabla_{g}) = \left[ 0 \right]_0 + \left[ 0 \right]_1 + \left[ \left( \frac{2}{\pi + \pi x^{4} + \pi y^{4} + 2 \, \pi x^{2} + 2 \, {\left(\pi + \pi x^{2}\right)} y^{2}} \right) \mathrm{d} x\wedge \mathrm{d} y \right]_2$$

integrate(integrate(e_class_form[2][[1,2]].expr(), x, -infinity, infinity).simplify_full(), y, -infinity, infinity)

$$\newcommand{\Bold}[1]{\mathbf{#1}}2$$

Chern-Weil Theory

Theorem

If $P\colon \mathfrak{gl}(n, \mathbb{C}) \to \mathbb{C}$ is an (under conjugation) invariant formal power series, then:

1. $P(\Omega^\nabla)$ can be globally defined and is closed,
2. $\left[ P(\Omega^\nabla) \right] \in H^{2*}(M;\mathbb{C})$ is independent of the choice of $\nabla$.

Proof (sketch):

1. Use the transformation behaviour of $\Omega^\nabla$ and invariant nature of $P$. Closedness follows from the Bianchi identity.
2. Connect two connections via homotopy.

Definition

We call $\left[ P(\Omega^\nabla) \right]$ a characteristic class of $M$.

Chern-Weil: Recipe

1. Choose a connection $\nabla$.

1. Compute its curvature form matrix $\Omega^\nabla$.

1. Plug it into an invariant formal power series $P$.

Some Important Classes

Name	Designation	Representative	Regime
Chern class	$c$	$\det\!\left( 1 + \frac{\Omega^\nabla}{2 \pi \mathrm{i}} \right)$	complex
Chern character	$\mathrm{ch}$	$\mathrm{tr}\!\left( \exp\!\left( \frac{\Omega^\nabla}{2 \pi \mathrm{i}}\right) \right)$	complex
Todd class	$\mathrm{Td}$	$\det\!\left(\frac{\frac{\Omega^\nabla}{2 \pi \mathrm{i}}}{1-\exp\left(\frac{\Omega^\nabla}{2 \pi \mathrm{i}}\right)}\right)$	complex
Pontryagin class	$p$	$\det\!\left( 1 - \frac{\left(\Omega^\nabla\right)^2}{4 \pi^2} \right)$	real
$\hat{A}$ class	$\hat{A}$	$\det\!\left( \sqrt{\frac{\frac{\mathrm{i}}{4 \pi} \Omega^\nabla}{\sinh\left( \frac{\mathrm{i}}{4 \pi} \Omega^\nabla \right)}}\right)$	real
Euler class	$e$	$\mathrm{Pf}\!\left( \frac{\Omega^\nabla}{2 \pi} \right)$	real

Implementation

$\phantom{\rightarrow}$ Define an affine connection $\nabla$

$\rightarrow$ Compute (or manually plug in) curvature form matrix $\Omega^\nabla$ w.r.t. some frame

$\rightarrow$ Compute $f\left(\frac{\Omega^\nabla}{2 \pi i}\right)$ using functional calculus

$\rightarrow$ Apply $\det$, $\mathrm{tr}$ or $\mathrm{Pf}$

$\Rightarrow$ Repeat until $M$ is covered and patch results together

Non-Spinable Manifold Example

cdim = 2
n = 2*cdim

M = Manifold(n, name='CP^' + str(cdim), latex_name=r'\mathbb{C}\mathrm{P}^' + str(cdim))

M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathbb{C}\mathrm{P}^2$$

U = M.open_subset('U')

cart_coords = tuple(['x_' + str(k) for k in range(cdim)] + ['y_' + str(k) for k in range(cdim)])
comp_coords = tuple(['z_' + str(k) for k in range(cdim)] + ['zb_' + str(k) + r':\bar{z}_' + str(k) for k in range(cdim)])

c_cart = U.chart(names=cart_coords); c_cart

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(U,(x_{0}, x_{1}, y_{0}, y_{1})\right)$$

c_comp = U.chart(names=comp_coords); c_comp

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(U,(z_{0}, z_{1}, {\bar{z}_0}, {\bar{z}_1})\right)$$

to_z  = tuple(c_cart[i] + I*c_cart[i+cdim] for i in range(cdim))
to_zb = tuple(c_cart[i] - I*c_cart[i+cdim] for i in range(cdim))

cart_to_comp = c_cart.transition_map(c_comp, to_z + to_zb); cart_to_comp.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} z_{0} & = & x_{0} + i \, y_{0} \\ z_{1} & = & x_{1} + i \, y_{1} \\ {\bar{z}_0} & = & x_{0} - i \, y_{0} \\ {\bar{z}_1} & = & x_{1} - i \, y_{1} \end{array}\right.$$

comp_to_cart = cart_to_comp.inverse()

def simp(expr):
    return expr.simplify_rational()

M.set_simplify_function(simp)

h = U.metric('h')

fU = c_comp.frame()
abs_values = [c_comp[i]*c_comp[i+cdim] for i in range(cdim)]
total_abs = sum(a for a in abs_values)

for i in range(cdim):
    for j in range(i+1):
        if i == j:
            h[fU,i,j+cdim] = (1+total_abs-abs_values[i])/(1+total_abs)^2
        else:
            h[fU,i,j+cdim] = (-c_comp[i+cdim]*c_comp[j])/(1+total_abs)^2
            h[fU,i+cdim,j] = (-c_comp[i]*c_comp[j+cdim])/(1+total_abs)^2

Fubini-Study Metric

h.display(c_comp)

$$\newcommand{\Bold}[1]{\mathbf{#1}}h = \left( \frac{z_{1} {\bar{z}_1} + 1}{{\left(z_{0} {\bar{z}_0} + z_{1} {\bar{z}_1} + 1\right)}^{2}} \right) \mathrm{d} z_{0}\otimes \mathrm{d} {\bar{z}_0} -\frac{z_{1} {\bar{z}_0}}{{\left(z_{0} {\bar{z}_0} + z_{1} {\bar{z}_1} + 1\right)}^{2}} \mathrm{d} z_{0}\otimes \mathrm{d} {\bar{z}_1} -\frac{z_{0} {\bar{z}_1}}{{\left(z_{0} {\bar{z}_0} + z_{1} {\bar{z}_1} + 1\right)}^{2}} \mathrm{d} z_{1}\otimes \mathrm{d} {\bar{z}_0} + \left( \frac{z_{0} {\bar{z}_0} + 1}{{\left(z_{0} {\bar{z}_0} + z_{1} {\bar{z}_1} + 1\right)}^{2}} \right) \mathrm{d} z_{1}\otimes \mathrm{d} {\bar{z}_1} + \left( \frac{z_{1} {\bar{z}_1} + 1}{{\left(z_{0} {\bar{z}_0} + z_{1} {\bar{z}_1} + 1\right)}^{2}} \right) \mathrm{d} {\bar{z}_0}\otimes \mathrm{d} z_{0} -\frac{z_{0} {\bar{z}_1}}{{\left(z_{0} {\bar{z}_0} + z_{1} {\bar{z}_1} + 1\right)}^{2}} \mathrm{d} {\bar{z}_0}\otimes \mathrm{d} z_{1} -\frac{z_{1} {\bar{z}_0}}{{\left(z_{0} {\bar{z}_0} + z_{1} {\bar{z}_1} + 1\right)}^{2}} \mathrm{d} {\bar{z}_1}\otimes \mathrm{d} z_{0} + \left( \frac{z_{0} {\bar{z}_0} + 1}{{\left(z_{0} {\bar{z}_0} + z_{1} {\bar{z}_1} + 1\right)}^{2}} \right) \mathrm{d} {\bar{z}_1}\otimes \mathrm{d} z_{1}$$

nab = h.connection(); nab

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_{h}$$

A = U.tangent_bundle().characteristic_class('AHat')

%%time
A_form = A.get_form(nab)

CPU times: user 1min 21s, sys: 4min 23s, total: 5min 45s
Wall time: 10min 7s

A_form.disp_exp(fU)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\hat{A}(TU, \nabla_{h}) = \left[ 1 \right]_0 + \left[ 0 \right]_1 + \left[ 0 \right]_2 + \left[ 0 \right]_3 + \left[ -\frac{1}{16 \, {\left(\pi^{2} z_{0}^{3} {\bar{z}_0}^{3} + \pi^{2} z_{1}^{3} {\bar{z}_1}^{3} + 3 \, \pi^{2} z_{0}^{2} {\bar{z}_0}^{2} + 3 \, \pi^{2} z_{0} {\bar{z}_0} + 3 \, {\left(\pi^{2} z_{0} z_{1}^{2} {\bar{z}_0} + \pi^{2} z_{1}^{2}\right)} {\bar{z}_1}^{2} + \pi^{2} + 3 \, {\left(\pi^{2} z_{0}^{2} z_{1} {\bar{z}_0}^{2} + 2 \, \pi^{2} z_{0} z_{1} {\bar{z}_0} + \pi^{2} z_{1}\right)} {\bar{z}_1}\right)}} \mathrm{d} z_{0}\wedge \mathrm{d} z_{1}\wedge \mathrm{d} {\bar{z}_0}\wedge \mathrm{d} {\bar{z}_1} \right]_4$$

A_genus = A_form[2*cdim][tuple(k for k in range(2*cdim))].expr().simplify_full()
for var in c_cart:
    A_genus = A_genus.integrate(var, -oo, oo).simplify_full()
A_genus

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{8}$$

$\Rightarrow$ $\mathbb{C}P^2$ is not spin!

Can we do better?

Fundamental Theorem of Symmetric Polynomials

For each symmetric polynomial $P \colon \mathfrak{gl}(n, \mathbb{C}) \to \mathbb{C}$ there exists a unique polynomial $Q$ such that

$$ P = Q(\sigma_1, \ldots, \sigma_n), $$

where $\sigma_i$ denotes the $i$-th elementary symmetric polynomial.

• Proof comes with algorithm (already implemented in Sage)

• $\sigma_i(\Omega^\nabla)$ can be computed via the characteristic polynomial algorithms for $\Omega^\nabla$

• No powers of $\Omega^\nabla$ involved

• $\Omega^\nabla$ is nilpotent of degree $\lfloor \frac{n}{2} \rfloor$ $\rightarrow$ speed-up in low dimensions

Special Case: The Pfaffian

Remark

$\mathrm{Pf} \colon \mathfrak{so}(2n) \to \mathbb{R}$ is invariant under $\mathrm{SO}(2n)$ conjugation.

• Bär-Faddeev-LeVerrier algorithm to compute ("division free") Pfaffian (C. Bär 2020)

• entails oriented orthonormal frames

Workaround (Chern 1963)

Let $(G_{ij})$ be the Gram matrix of a pseudo-Riemannian metric w.r.t. to some not necessarily ON but oriented frame. Then the matrix

$$G \cdot \Omega$$

is skew-symmetric.

Idea now: Take $\mathrm{Pf}(G \cdot \Omega)$ and normalize by $\sqrt{|\det(G)|}$.

Generators of Characteristic Classes

Complex setup:

• $c_i(M) = \left[ \sigma_i\left( \frac{\Omega^\nabla}{2 \pi i} \right) \right]$

Real setup:

Choose metric connection such that $\Omega^\nabla$ can be chosen skew-symmetric:

• $p_i(M) = (-1)^i c_{2i}(M)$

If $M$ is orientable:

• $e(M) = \left[\mathrm{Pf}\left( \frac{\Omega^\nabla}{2 \pi} \right)\right]$

Generators of Characteristic Classes II

Let $R$ be a ring (typically $R= \mathbb{Z}, \mathbb{Q}, \mathbb{R}, \mathbb{C}$) then the following polynomial rings give the set of characteristic classes:

• $R[c_1, \ldots, c_n]$ if the tangent bundle is complex

• $R\left[p_1, \ldots, p_{\lfloor \frac{n}{2} \rfloor}\right]$ if the tangent bundle is real and non-orientable

• $R\left[p_1, \ldots, p_k, e\right]$ if the tangent bundle is real and orientable, $n$ odd, and $n = 2k+1$

• $R\left[p_1, \ldots, p_k, e\right]\big/\left(e^2-p_k\right)$ if the tangent bundle is real, $n=2k$ and the bundle is orientable

$\rightarrow$ Implement these structures in Sage to obtain all characteristic classes directly and more easily

Future Prospect: Transgression Forms

Suppose $\nabla,\nabla'$ are two connections. Then:

\begin{align*} \int_M \kappa\big(M, \nabla \big) - \kappa\big(M, \nabla'\big) &= \int_{M} \mathrm{d} Q\big(M, \nabla, \nabla' \big) \\ &= \int_{\partial M} Q\big(M, \nabla, \nabla' \big) \end{align*}

• $\partial M = \emptyset$ implies that $\kappa(M)$ is a geometric invariant

• $Q\big(M, \nabla, \nabla' \big)$ is called transgression form

References

1. M. F. Atiyah, I. M. Singer, The Index of Elliptic Operators: III (1968) in Annals of Mathematics.
2. C. Bär, The Faddeev-LeVerrier algorithm and the Pfaffian (2020), available at https://arxiv.org/abs/2008.04247.
3. S.-S. Chern, Pseudo-Riemannian Geometry and the Gauss-Bonnet Formula (1963) in An. da Acad. Brasileira de Ciencias.
4. M. Jung, Characteristic classes in computer algebra (2020), available at https://arxiv.org/abs/2006.13788.